group 'net.soti.go.plugin'

apply plugin: 'java'

sourceCompatibility = 1.8 // java 8
targetCompatibility = 1.8

repositories {
    maven {
        url 'http://sotiartifacts:8081/artifactory/globalmaven/'
    }
    mavenLocal()
}

jar {
    from(configurations.compile) {
        into "lib/"
    }
    archiveName project.name + '.' + project.version +'.jar'
}

version = rootProject.version
def projectName = rootProject.group + '.' + rootProject.name
def pluginDesc = [
        id         : projectName,
        version    : rootProject.version,
        goCdVersion: '16.12.0',
        name       : 'SOTI Powershell GoCD task plugin',
        description: 'GoCD task plugin that execute powershell',
        vendorName : 'SOTI Inc',
        vendorUrl  : 'https://www.soti.net'
]

println "ProjectName = {$rootProject.name}, this.name = {$name}, version {$rootProject.version}"
processResources {
    from("resource-templates") {
        filesMatching('plugin.xml') {
            println pluginDesc
            expand pluginDesc
        }
    }
}

dependencies {
    compileOnly group: 'cd.go.plugin', name: 'go-plugin-api', version: '16.11.0'
    compile group: 'com.google.guava', name: 'guava', version: '19.0'
    compile group: 'org.apache.commons', name: 'commons-lang3', version: '3.4'
    compile group: 'commons-io', name: 'commons-io', version: '2.4'
    compile group: 'com.google.code.gson', name: 'gson', version: '2.7'
    compile group: 'org.apache.httpcomponents', name: 'httpclient', version: '4.5.2'

    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile group: 'org.hamcrest', name: 'hamcrest-library', version: '1.3'
    testCompile group: 'org.mockito', name: 'mockito-core', version: '2.0.96-beta'
}